注册会员 登录
Project1 返回首页

zh99998的个人空间 https://rpg.blue/?42757 [收藏] [复制] [分享] [RSS]

日志

你抽。。。你再抽我拿VBS来XE你

热度 2已有 547 次阅读2010-7-18 18:01 |个人分类:66RPG|

你Y的再抽。。再抽我拿VBS来XE你。。
以下是vbs代码
-----------------------------------------------------------------
'遇到抽风自动重启进程池 by zh99998 2010-7-16
'only for IIS7 请用管理员身份运行
'2010-7-18更新,解决缓存问题

'配置部分
AppPool="66RPG" '应用池名称
URL1="http://bbs.66rpg.com/appreset_test.php" '测试接口页面1
URL2="http://bbs.66rpg.com/appreset_test.htm" '测试接口页面2
'因为抽风时只是不能解析php,于是检测到php无法访问时,检测另一个非php页面,若这个页面也不能访问,则不重启进程池
WaitTime=100000   '每次检测的时间间隔,单位毫秒
LogFile="d:\AppPool_reset_log.txt" '日志文件路径
TTL=5 '连续重启上限,这个是为了防止由于某些异常而不断重启进程池

'配置部分结束

Set FSO = CreateObject("Scripting.FileSystemObject")
Set LogFile = FSO.OpenTextFile (LogFile, 8, True)
Set ws = CreateObject("Wscript.shell")
t=TTL
LogFile.WriteLine(now()&" 检测程序启动")
Do
  Set http = CreateObject("Microsoft.XMLHTTP")
  http.Open "GET",URL1&"?test="&now(),0
  http.Send()
  if http.responseText <> "1" then
    Set http = CreateObject("Microsoft.XMLHTTP")
    http.Open "GET",URL2&"?test="&now(),0
    http.Send()
    if http.responseText = "1" then
      if t>0 then
        LogFile.WriteLine(now()&" 检测到抽风,尝试重启进程池")
        ws.run "%windir%\system32\inetsrv\appcmd.exe stop APPPOOL "&AppPool,0,true
        ws.run "%windir%\system32\inetsrv\appcmd.exe start APPPOOL "&AppPool,0,true
        t=t-1
      else
        LogFile.WriteLine(now()&" 重启进程池无效,持续抽风中") '超过连续重启次数上限
      end if
    else
      LogFile.WriteLine(now()&" 接口页面访问失败")
      t=TTL
    end if
  else
    'LogFile.WriteLine(now()&" 一切正常") '如果不需要正常记录,可以把这句注释掉
    t=TTL
  end if
wscript.sleep WaitTime
Loop

鸡蛋

鲜花

发表评论 评论 (3 个评论)

回复 紫苏 2010-7-19 03:38
这么暴力……
那重启期间总会有段时间无法访问了……
回复 zh99998 2010-7-19 07:25
紫苏: 这么暴力……
那重启期间总会有段时间无法访问了……
不会的,重启很快1秒钟之内就能搞定,不过因为每次检测有时间间隔,加上抽风后要先卡一个超时才能看到读到回复,所以抽风一次还是会有2min左右不能访问的,嘛,不过作为一个临时解决方案已经很不错了
回复 小角色 2010-7-19 09:09
ZH酱加油~

facelist doodle 涂鸦笔

您需要登录后才可以评论 登录 | 注册会员

拿上你的纸笔,建造一个属于你的梦想世界,加入吧。
 注册会员
找回密码

站长信箱:[email protected]|手机版|小黑屋|无图版|Project1游戏制作

GMT+8, 2022-1-19 15:59

Powered by Discuz! X3.1

© 2001-2013 Comsenz Inc.

返回顶部